E-Mail Drucken

Einige BIOS- und Systeminformationen legt Windows in der Registrierung ab. Diese Informationen werden zum Teil unter den Systemeigenschaften (je nach Betriebssystem) angezeigt. Dieser Tipp zeigt nun an, wo welche Informationen aus der Registrierung entnommen werden können.

So geht's:

• Starten Sie ...\windows\regedit.exe bzw. ...\winnt\regedt32.exe.
• Klicken Sie sich durch folgende Schlüssel (Ordner) hindurch:
  HKEY_LOCAL_MACHINE
  HARDWARE
  DESCRIPTION
  System
• Folgende BIOS-Informationen können nun entnommen werden:

  Schlüssel:	Schlüsseltyp:	Info:
  SystemBiosDate	REG_SZ	BIOS Datum vom Motherboard
  SystemBiosVersion	REG_MULTI_SZ	BIOS Version(en) und ggf. Hersteller vom Motherboard
  VideoBiosDate	REG_SZ	BIOS Datum von der Grafikkarte
  VideoBiosVersion	REG_MULTI_SZ	BIOS Version(en) und ggf. Hersteller von der Grafikkarte

• Klicken Sie sich durch folgende Schlüssel (Ordner) hindurch:
  HKEY_LOCAL_MACHINE
  HARDWARE
  DESCRIPTION
  System
  CentralProcessor
  0
• Folgende Prozessor-Informationen können nun entnommen werden:

  Schlüssel:	Schlüsseltyp:	Info:
  ProcessorNameString	REG_SZ	Hersteller und Prozessorname des ersten Prozessors

VBScript (zeigt die o.g. Informationen in einer Nachrichtendialog an):

• Speichern Sie folgenden Inhalt in einer Datei mit der Erweiterung ".vbs" ab. Mit einem Doppelklick auf die Datei kann das Skript gestartet werden:

  Option Explicit

  const HKEY_LOCAL_MACHINE = &H80000002
  const strKeyPath = "HARDWARE\DESCRIPTION\System"
  const strComputer = "."

  Dim bReg, strValue, arrValues, BIOS_Version, BIOS_Date, Video_Version, Video_Date, Processor_Name

  Set bReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")

  bReg.GetMultiStringValue HKEY_LOCAL_MACHINE, strKeyPath, "SystemBiosVersion" ,arrValues
    For Each strValue In arrValues
  BIOS_Version = BIOS_Version & vbCrLf & vbTab & strValue
  Next

  bReg.GetStringValue HKEY_LOCAL_MACHINE, strKeyPath, "SystemBiosDate" ,BIOS_Date

  bReg.GetMultiStringValue HKEY_LOCAL_MACHINE, strKeyPath, "VideoBiosVersion" ,arrValues

  For Each strValue In arrValues
    Video_Version = Video_Version & vbCrLf & vbTab & strValue
  Next

  bReg.GetStringValue HKEY_LOCAL_MACHINE, strKeyPath, "VideoBiosDate" ,Video_Date

  bReg.GetStringValue HKEY_LOCAL_MACHINE, strKeyPath & "\CentralProcessor\0", "ProcessorNameString" ,Processor_Name

  WScript.Echo "BIOS-Version: " & BIOS_Version & vbCrLf & "BIOS-Date: " & BIOS_Date & vbCrLf & vbCrLf &_
  "Grafik-Version: " & Video_Version & vbCrLf & "Grafik-Datum: " & Video_Date & vbCrLf & vbCrLf &_
  "Prozessor: " & Processor_Name

Hinweis:

• Ändern Sie bitte nichts anderes in der Registrierungsdatei. Dies kann zur Folge haben, dass Windows und/oder Anwendungsprogramme nicht mehr richtig arbeiten.